@@
@@ DarrienSpace Installer, Version 1
@@ This is part 2.  There is at least one other section after this one.
@@ Please do the previous sections in order before executing this one.
@@ No editing of this file should be necessary for PennMUSH
@@
@@ I haven't tested this on Tiny, though.
@@
@@ It also shouldn't be necessary to pre-create objects
@@
@@
@set me=Quiet
&DO_MAN_LAND Master Nav-Comp=@pemit %1=[switch(u(fun_can-land?,get(v(data_shipdb)/trans_[setr(5,first(after(before(%0,/),ON)))]),setr(4,first(after(rest(%0),/))),switch(first(after(%0,%q4)),ON,,first(after(%0,%q4))),%1),0|*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] This ship is not currently in space and can not land.,1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] This ship currently is incapable of landing.,1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] No ship by that transponder %(%q5%) is available to land on within this system.,1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] That ship %(%q5%) is out of range for landing purposes.,1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] That ship %(%q5%) does not have a hangar available by the name: %q4,1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Incorrect password for Hangar %q4 on %q5.,1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] No room is available in hangar %q4 on ship %q5.,1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] That ship %(%q5%) currently has its shields up.,1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] A ship can not land on itself.,1|1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You can not land while in combat.,1|1|1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You can not land a ship while docked.,1|1|1|1|1|1|1|1|1|1|1|0,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Only the pilot can land the ship.,1|1|1|1|1|1|1|1|1|1|1|1,<[ansi(c,NAVIGATION)]> Ship landed successfully.[remit(%2,[name(%1)] landed the ship successfully.)][set(v(data_systemdb),system_%q3:[setdiff(get(v(data_systemdb)/system_%q3),%q1)])][set(%q2,hangar_%q4:[replace(get(%q2/hangar_%q4),3,sub(extract(get(%q2/hangar_%q4),3,1),extract(get(%q1/stat_stats),10,1,|)))])][tel(%q1,extract(get(%q2/hangar_%q4),1,1))][iter(iter(lattr(%q1/d_*),get(%q1/##)),link(##,loc(%q1)))][u(fun_land-notify)][wipe(%q1/location)][wipe(%q1/system)])]
&DO_MAN_TAKEOFF Master Nav-Comp=@remit [switch(hasattr(v(ship),quiet),1,v(ship),%2)]=[switch(u(fun_can-takeoff?,%1),1,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You can not takeoff at this point in time.  Make sure the ship is landed%, and that you are the current pilot.,0,<[ansi(c,NAVIGATION)]> [get(%q1/trans)] takes off.[set(setr(0,v(data_systemdb)),SYSTEM_[setr(3,get(%q2/system))]:[setunion(get(%q0/system_%q3),%q1)])][set(%q2,setr(0,hangar_[get(%q4/hangar_name)]):[replace(get(%q2/%q0),3,add(extract(get(%q2/%q0),3,1),extract(get(%q1/stat_stats),10,1,|)))])][set(%q1,location:[get(%q2/location)])][set(%q1,system:%q3)][tel(%q1,v(space))][u(fun_enter-space-notify)][iter(iter(lattr(%q1/d_*),get(%q1/##)),link(##,v(space)))])]
&DO_CBT_HELP Master Nav-Comp=@pemit %1=%r[u(help_header,CBT)][iter(lnum(1,add(1,round(fdiv(words(v(cbt_commands)),2),0))),%r[u(help_cbt_[extract(v(cbt_commands),##,1)])])]
&DO_COM_HELP Master Nav-Comp=@pemit %1=%r[u(Help_Header,COM)][iter(v(COM_commands),%r[u(help_com_##)])]
&DO_MAN_HELP Master Nav-Comp=@pemit %1=%r[u(Help_Header,MAN)][iter(v(man_commands),%r[u(help_man_##)])]
&DO_NAV_HELP Master Nav-Comp=@pemit %1=%r[u(Help_Header,NAV)][iter(v(NAV_commands),%r[u(help_nav_##)])]
&DO_JUMP_HELP Master Nav-Comp=@pemit %1=%r[u(Help_Header,JUMP)][iter(v(JUMP_commands),%r[u(help_jump_##)])]
&DO_SCAN_HELP Master Nav-Comp=@pemit %1=%r[u(Help_Header,SCAN)][iter(v(scan_commands),%r[u(help_scan_##)])]
&DO_SCAN_PASSIVE Master Nav-Comp=@pemit %1=[u(fun_setqueues)][u(fun_setqueues2,setr(2,get(v(data_shipdb)/trans_[first(after(%0,PASSIVE))])))][switch(u(fun_scancheck?,extract(get(%q1/comm_stats),2,1,|)),0|*,[u(fun_scan-not-space)],1|0*,<[ansi(c,SENSORS)]> [ansi(r,Error:)] You have entered "[after(%0,PASSIVE%b)]" as the Transponder of the ship you'd like to scan.  Currently%, that can not be seen at this time.,1|1|0,<[ansi(c,SENSORS)]> [ansi(r,Error:)] That ship %([get(%q2/trans)]%) is out of range for that type of scan.,1|1|1,[u(fun_disp-norm-scan,P)])]
&DO_SCAN_FOCUS Master Nav-Comp=@pemit %1=[u(fun_setqueues)][u(fun_setqueues2,setr(2,get(v(data_shipdb)/trans_[first(after(%0,FOCUS))])))][switch(u(fun_scancheck?,extract(get(%q1/comm_stats),4,1,|)),0|*,[u(fun_scan-not-space)],1|0*,<[ansi(c,SENSORS)]> [ansi(r,Error:)] You have entered "[after(%0,FOCUS%b)]" as the Transponder of the ship you'd like to scan.  Currently%, that can not be seen at this time.,1|1|0,<[ansi(c,SENSORS)]> [ansi(r,Error:)] That ship %([get(%q2/trans)]%) is out of range for that type of scan.,1|1|1,[u(fun_disp-focus-scan)])]
&DO_NAV_LOCATION Master Nav-Comp=@pemit %1=[repeat(_,76)]%rCurrent Location%r[repeat(-,76)]%r[switch(loc(setr(1,v(ship))),v(space),[ljust(System,30,.)]:[edit(setr(0,get(%q1/system)),|,%,)]%r%b%b[ljust(System Information,28,.)]:Points of Interest[iter(grep(v(data_systemdb),NAME_SYSTEM_*,%q0),%r[space(33)][after(##,SYSTEM_)])]%r%r[ljust(Location,30,.)]:[edit(get(%q1/location),|,%,)],v(hyperspace),This ship is currently in Hyperpace%rDestination: [edit(extract(get(%q1/jumping),1,1),|,%,)],[u(fun_scan-not-space)])]
&DO_NAV_MOVETO Master Nav-Comp=@pemit %1=[switch(u(fun_can-go-to-coord?,setr(0,after(%0,MOVETO%b)),%1),0|*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You must be in regular space in order to move the ship.,1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The ship is currently unable to move.,1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] This ship is currently docked and can not move.,1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Either "[edit(%q0,%b,%,)]" is not an X%,Y%,Z numberical destination%, "[edit(%q0,%b,%,)]" is not a valid transponder%, or the destination is currently out of range for this type of move.,1|1|1|1|0,<[ansi(c,NAVIGATION)]> Only the pilot can move the ship.,1|1|1|1|1,<[ansi(c,NAVIGATION)]> Destination reached.[set(%q1,location:%q7|%q8|%q9)][u(fun_move-notify)])]
&DO_NAV_AUTO Master Nav-Comp=@swi [setr(0,first(after(%0,AUTO%b)))]=ON,{@pemit %1=[switch(u(fun_can-autopilot,%1),0|*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The autopilot must be set before it can be engaged.  Use: NAV/AUTOPILOT TO X%,Y%,Z or NAV/AUTOPILOT TO <TRANS>,1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You must be in space in order to engage the autopilot.,1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The ship is already at the coordinates specified in the Autopilot.,1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The Ship is currently docked and can not engage the autopilot.,1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The ship is currently incapable of moving.,1|1|1|1|1|0*,<NAVIGATIN> The Autopilot is already engaged.,1|1|1|1|1|0,<[ansi(c,NAVIGATION)]> Only the pilot can move the ship.,1|1|1|1|1|1|1,<[ansi(c,NAVIGATION)]> Autopilot engaged.[setq(0,GO!)][set(%q1,auto:ON)])];@swi %q0=GO!,{@tr me/Fun_do_auto=%q4,%q5,%q6}},OFF,@pemit %1=[switch(get(setr(1,v(ship))/auto),ON,<[ansi(c,NAVIGATION)]> Autopilot disengaged.[set(%q1,auto:OFF)],<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Autopilot is not currently engaged.)],DISPLAY,@pemit %1=<[ansi(c,NAVIGATION)]> Autopilot set to: [edit(get(v(ship)/autopilot),|,%,)],TO,[u(fun_Nav_auto_set,%0,%1)],@pemit %1=<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "%0" is not a valid switch for that command.
&DO_JUMP_CALC Master Nav-Comp=@pemit %1=[switch(u(fun_cancalc?,setr(0,after(%0,TO%b))),0*,<[ansi(c,JUMP)]> [ansi(r,Error:)] You must be in space to properly calculate jumps.,1|0*,<[ansi(c,JUMP)]> [ansi(r,Error:)] This ship is incapable of jumping.,1|1|0*,<[ansi(c,JUMP)]> [ansi(r,Error:)] [edit(%q0,%b,%,)] is either invalid system coordinates%, or [edit(%q0,%b,%,)] is an invalid system name.,1|1|1|0,<[ansi(c,JUMP)]> [ansi(r,Error:)] The Navigational Computer is full.  You must delete a jump before a new one will be added.,1|1|1|1,<[ansi(c,JUMP)]> Route calculated and recorded as Jump Number [setr(0,add(words(lattr(%q1/Jump_*)),1))].[remit(%2,[name(%1)] plots a jump in the Navcomputer.)][set(%q1,JUMP_%q0:%q3 %q7|%q8|%q9 [setr(4,mul(extract(get(%q1/stat_stats),7,1,|),round(dist3d(%q4,%q5,%q6,%q7,%q8,%q9),0)))])] Estimated travel time: [timestring(%q4)])]
&DO_JUMP_DEL Master Nav-Comp=@pemit %1=[switch([isnum(setr(0,after(%0,DEL%b)))]|[hasattr(setr(1,v(ship)),jump_%q0)],0*,<[ansi(c,JUMP)]> [ansi(r,Error:)] "%q0" is not a valid Jump Number.,1|0,<[ansi(c,JUMP)]> [ansi(r,Error:)] Jump "%q0" does not exist on this Navigational Computer.,1|1,<[ansi(c,JUMP)]> Jump %q0 deleted.[remit(%2,[name(%1)] removes a calculated jump from the Navcomputer.)][setq(4,words(lattr(%q1/jump_*)))][wipe(%q1/jump_%q0)][switch(%q4,1,,%q0,,[iter(lnum(%q0,sub(%q4,1)),set(%q1,jump_##:[get(%q1/jump_[add(##,1)])]))][wipe(%q1/jump_%q4)])])]
&DO_JUMP_INFO Master Nav-Comp=@pemit %1=JUMP INFORMATION%r[repeat(_,76)]%r#%b%b[ljust(FROM:,15)][ljust(TO:,15)][ljust(RANGE:,10)][rjust(Trav Time:,10)]%b%b%b%bDestinations:%r[repeat(=,76)][switch(setr(0,words(lattr(setr(1,v(ship))/jump_*))),0,%rNo Jumps Recorded.,iter(lnum(1,%q0),%r[ljust(##,3)][ljust(setr(3,extract(get(%q1/JUMP_##),1,1)),15)][ljust(setr(4,extract(get(%q1/JUMP_##),2,1)),15)][rjust(u(fun_calc_dist,%q3,%q4),6)][rjust(timestring(extract(get(%q1/JUMP_##),3,1)),14)][space(4)][switch(words(setr(0,grep(v(data_systemdb),NAME_SYSTEM_*,extract(get(%q1/JUMP_##),2,1)))),0,,1,after(%q0,SYSTEM_),[after(first(%q0),SYSTEM_)][map(fun_disp_points,after(%q0,first(%q0)))])]%r[repeat(-,76)]))]%r[repeat(=,76)]%rCURRENT SYSTEM: [switch(hasattr(%q1,system),1,edit(get(%q1/system),|,%,),Unavailable)]
&DO_JUMP_UNJUMP Master Nav-Comp=@remit [switch(hasattr(v(ship),QUIET),1,v(ship),%2)]=[switch([switch(loc(setr(1,v(ship))),v(hyperspace),1,0)]|[gte(secs(),setr(4,extract(get(%q1/jumping),2,1)))],0*,[pemit(%1,<[ansi(c,JUMP)]> [ansi(r,Error:)] The ship is not currently in Hyperspace.)],1|0,[pemit(%1,<[ansi(c,JUMP)]> [ansi(r,Error:)] The ship has not reached its destination yet.  The hyperdrive can be disengaged in: [timestring(sub(%q4,secs()))].)],1|1,<[ansi(c,JUMP)]> Hyperdrive disengaged.[set(%q1,system:[setr(3,extract(get(%q1/jumping),1,1))])][set(v(data_systemdb),SYSTEM_%q3:[setunion(get(v(data_systemdb)/SYSTEM_%q3),%q1)])][tel(%q1,v(space))][wipe(%q1/jumping)][u(fun_enter-space-notify)])]
&DO_MAN_DOCK Master Nav-Comp=@pemit %1=[switch(u(fun_candock?,setr(0,after(%0,DOCK WITH%b)),%1),0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You must be in space to dock.,1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] This ship is currently incapable of docking.,1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "[before(first(%q0),/)]" is either not a valid Transponder%, or is not in this system.,1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] You must be in the same location as [get(%q2/trans)] in order to dock with it.,1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "%q3" is not a valid tube on this ship.,1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "%q4" is not a valid tube on [get(%q2/trans)].,1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] [get(%q2/trans)] is currently incapable of docking.,1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "%q4" on [get(%q2/trans)] appears to be in use.,1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The docking code for "%q4" on [get(%q2/trans)] does not match "%q7".,1|1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] A ship can not dock with itself.,1|1|1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Can not dock while in combat.,1|1|1|1|1|1|1|1|1|1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Tube '%q3' is already in use.,1|1|1|1|1|1|1|1|1|1|1|1|0,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Only the pilot can perform docking manuevers.,1|1|1|1|1|1|1|1|1|1|1|1|1,<[ansi(c,NAVIGATION)]> Dock with [get(%q2/trans)] successful.[remit(%2,[name(%1)] docks the ship with [get(%q2/trans)])][set(%q1,dyn_stats:[replace(get(%q1/dyn_stats),10,1,|)])][set(%q2,dyn_stats:[replace(get(%q2/dyn_stats),10,1,|)])][set(%q5,docked:[home(%q6)])][link(%q5,home(%q6))][set(%q6,docked:[home(%q5)])][link(%q6,home(%q5))][set(%q1,d_%q3:[get(%q1/d_%q3)] %q2)][set(%q2,d_%q4:[get(%q2/d_%q4)] %q1)])]
&DO_MAN_UNDOCK Master Nav-Comp=@pemit %1=[switch(u(fun_canundock?,setr(0,after(%0,UNDOCK%b)),%1),0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] This ship is not docked with anything.,1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] "%q3" is not a valid docking tube on this ship.,1|1|0*,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] The specified docking tube does not appear to be in use.,1|1|1|0,<[ansi(c,NAVIGATION)]> [ansi(r,Error:)] Only the pilot can undock the ship.,1|1|1|1,<[ansi(c,NAVIGATION)]> Undocking successful.[remit(%2,[name(%1)] has undocked the ship from [get(%q2/trans)])][wipe(%q5/docked)][link(%q5,loc(%q1))][wipe(%q6/docked)][link(%q6,loc(%q2))][set(%q1,d_%q3:[squish(edit(get(%q1/d_%q3),%q2,))])][set(%q2,d_%q4:[squish(edit(get(%q2/d_%q4),%q1,))])][set(%q1,dyn_stats:[replace(get(%q1/dyn_stats),10,t(words(iter(lattr(%q1/d_*),switch(words(matchall(get(%q1/##),#*)),1,,##)))),|)])][set(%q2,dyn_stats:[replace(get(%q2/dyn_stats),10,t(words(iter(lattr(%q2/d_*),switch(words(matchall(get(%q2/##),#*)),1,,##)))),|)])])]
&DO_COM_CHAN Master Nav-Comp=@pemit %1=[switch(first(rest(%0)),SET,[u(fun_chan_set,%0)],LIST,[u(fun_chan_list)],switch(isnum(setr(0,last(first(%0,=)))),1,[u(fun_chan_transmit,%0,%3)],<COMMUNICATION> [ansi(r,Error:)] "[first(rest(%0))]" is not a valid function of this command.  Please check COMM/HELP for assistance.))]
&DO_COM_RADIO Master Nav-Comp=@pemit %1=[u(fun_radioqueues,setr(0,last(first(%0,=))))][switch([t(%q2)]|[lt(dist3d(%q4,%q5,%q6,%q7,%q8,%q9),extract(get(%q1/comm_stats),5,1,|))]|[switch(loc(%q1),v(hyperspace),0,1)],0*,<COMMUNICATION> [ansi(r,Error:)] "%q0" does not appear to be a valid Transponder.  It's possible "%q0" is in hyperspace.,1|0*,<COMMUNICATION> [ansi(r,Error:)] "%q0" appears to be out of range of this ship's long range communications.,1|1|0,<COMMUNICATION> [ansi(r,Error:)] Radio communication is impossible while the ship is in hyperspace.,1|1|1,[remit(%2,<COMMUNICATION> You transmit to %q0: "[edit(after(rest(%3),=),%/,)]")][remit(get(%q2/cockpit),<COMMUNICATION> Radio transmission from [get(%q1/trans)] -- "[edit(after(rest(%3),=),%/,)]")])]
&DO_CBT_WEAPON Master Nav-Comp=
&DO_CBT_DISPLAY Master Nav-Comp=@pemit %1=[u(fun_setqueues)][switch(match(loc(%q1),v(space)),0,<[ansi(c,COMBAT)]> You must be in real space in order to utilize these combat commands.,[switch(setr(0,extract(get(%q1/combat_stats),1,1,|)),0,<[ansi(c,COMBAT)]> You are not in combat.  All combat groupings %(if any%) within normal scanner range will be displayed.%r[u(fun_cbt-display-head)][setq(0,*)][map(fun_cbt-display,get(v(data_systemdb)/system_[get(%q1/system)]))]%r[repeat(=,76)],<[ansi(c,COMBAT)]> You are in combat group '%q0'.[u(fun_cbt-display-head)][map(fun_cbt-display,get(v(data_systemdb)/system_[get(%q1/system)]))]%r[repeat(=,76)])])]
&DO_MISC_PILOT Master Nav-Comp=@remit %2=[switch(and(hastype(%1,player),match(rest(%0),get(setr(1,v(ship))/code))),1,<[ansi(c,CONSOLE)]> [name(%1)] takes the con. %r<OOC: [name(%1)]'s stats will be used for Piloting Purposes.>[set(%q1,pilot:%1)],<[ansi(c,CONSOLE)]> [ansi(r,Error:)] Incorrect code%, or incorrect player type.)]
&DO_CBT_LOG Master Nav-Comp=@pemit %1=[switch([hasattr(setr(1,v(ship)),cbt_log)][match(rest(%0),CLEAR)],0*,<[ansi(c,COMBAT)]> [ansi(r,Error:)] No Combat Log is available for display.,11,<[ansi(c,COMBAT)]> Combat log erased.[wipe(%q1/cbt_log)],10,<[ansi(c,COMBAT)]> Displaying combat log...[iter(get(%q1/cbt_log),%r-##,|)])]
&DO_MISC_STATUS Master Nav-Comp=@pemit %1=[ljust(----=< Status Display for [get(setr(1,v(ship))/trans)] >=,76,-)]%r%b%b%bStatus: [extract(setr(4,get(%q1/dyn_stats)),5,1,|)]%r%b%b%bShield: [ljust([extract(%q4,1,1,|)]%/[extract(%q4,4,1,|)],10)]%bHull: [ljust(extract(%q4,2,1,|)/[extract(setr(5,get(%q1/stat_stats)),2,1,|)],12)]Fuel - [extract(%q4,6,1,|)]%/[extract(%q5,6,1,|)]%r%b%b%bSystem: [ljust(switch(loc(%q1),v(space),edit(get(%q1/system),|,%,),v(hyperspace),-- HYPERSPACE --,edit(get(get(loc(%q1)/ship)/system),|,%,)),16)]Location: [switch(loc(%q1),v(space),edit(get(%q1/location),|,%,),v(hyperspace),N/A,[name(get(loc(%q1)/ship))]%([get(loc(%q1)/hangar_name)]%))]%r%b%b%b[ljust(Ship Speed %(Real Space%): [extract(%q5,1,1,|)],35)]Hyperdrive Speed: X[fdiv(extract(%q5,7,1,|),10)]%r%b%b%b[ljust(Jumps in NavComp: [words(lattr(%q1/jump_*))]%/[extract(%q5,9,1,|)],35)]Ship Size: [extract(%q5,10,1,|)]%r%b%b%b[ljust(Maximum Radio Channels: [extract(get(%q1/comm_stats),1,1,|)],35)]Long Range Communication: [extract(get(%q1/comm_stats),5,1,|)]%r-Ship Systems Functionality-%r%b%b%b[ljust(Hyperdrive: [switch(extract(%q4,8,1,|),1,Yes,No)],18)][ljust(Landing Gear: [switch(extract(%q4,9,1,|),1,Yes,No)],20)]Docking Apparatus: [switch(extract(%q4,7,1,|),1,Yes,No)]%r%b%b%bNormal Scanner Range: [extract(get(%q1/comm_stats),3,1,|)]%r%b%b%bPassive Scanner Range: [extract(get(%q1/comm_stats),2,1,|)]%r%b%b%bFocus Scanner Range: [extract(get(%q1/comm_stats),4,1,|)]%r[ljust(-Weapon Status-,51)]Range Modifications%r[ljust(Num,4)][ljust(Name,40)][ljust(Ammo,6)][ljust(0-10:,6)][ljust(11-100:,8)][ljust(101-500:,9)]>500:[switch(words(lattr(%q1/weapon_*)),0,%r-- This ship is unarmed --,map(fun_status-disp-weap,lattr(%q1/weapon_*)))]
&DO_CBT_SHIELDS Master Nav-Comp=@remit %2=[switch(t(setr(0,extract(get(setr(1,v(ship))/dyn_stats),4,1,|))),0,<[ansi(c,CONSOLE)]> This ship is incapable of raising shields.,switch(lt(extract(get(%q1/dyn_stats),1,1,|),%q0),1,<[ansi(c,CONSOLE)]> Shields up%, at %q0.[set(%q1,dyn_stats:[replace(get(%q1/dyn_stats),1,%q0,|)])][u(fun_notify-results,<[ansi(c,SENSORS)]> [get(%q1/trans)] raises its shields.)],<[ansi(c,CONSOLE)]> Shields lowered.[set(%q1,dyn_stats:[replace(get(%q1/dyn_stats),1,0,|)])][u(fun_notify-results,<[ansi(c,SENSORS)]> [get(%q1/trans)] lowers its shields.)]))]
&DO_MISC_QUIET Master Nav-Comp=@remit %2=[switch(hasattr(setr(1,v(ship)),quiet),1,[name(%1)] sets the Quiet feature to OFF.[wipe(%q1/quiet)],[name(%1)] sets the Quiet feature to ON.[set(%q1,quiet:1)])]
&DO_MISC_CODE Master Nav-Comp=@pemit %1=[switch(and(match(setr(0,first(rest(%0))),get(setr(1,v(ship))/code)),t(setr(2,first(after(%0,TO%B))))),1,<[ansi(c,CONSOLE)]> You change the ship code to '%q2'.[set(%q1,code:%q2)],0,<[ansi(c,CONSOLE)]> [ansi(r,Error:)] Either '%q0' does not match the current code%, or '%q2' is not a valid new code.)]
&DO_JUMP_ETA Master Nav-Comp=@pemit %1=[switch(loc(setr(1,v(ship))),v(hyperspace),<[ansi(c,JUMP)]> The ship may be brought out of lightspeed:%r[switch(gte(secs(),setr(0,extract(get(%q1/jumping),2,1))),1,Immediately.  Use JUMP/UNJUMP,timestring(sub(%q0,secs())))],<[ansi(c,JUMP)]> [ansi(r,Error:)] This ship isn't in hyperspace.)]
&DO_JUMP_DEST Master Nav-Comp=@pemit %1=[switch([hasattr(setr(1,v(ship)),system)][isnum(rest(%0))],0*,<JUMP> Error: You must be in real space in order to execute this command.,10,<JUMP> Error: You must specify a minimum distance. '[rest(%0)]' is not valid.,11,<JUMP> Processing...[setq(4,extract(get(%q1/system),1,1,|))][setq(5,extract(get(%q1/system),2,1,|))][setq(6,extract(get(%q1/system),3,1,|))][iter(lattr(setr(0,v(data_systemdb))/name_system_*),[setq(7,extract(get(%q0/##),1,1,|))][setq(8,extract(get(%q0/##),2,1,|))][setq(9,extract(get(%q0/##),3,1,|))][switch(lte(setr(2,dist3d(%q4,%q5,%q6,%q7,%q8,%q9)),rest(%0)),1,%r%t[ljust(after(##,NAME_SYSTEM_),20,.)]: [ljust(edit(get(%q0/##),|,%,),15)]Dist - %q2)])])]
@@ End of part 2.
@set me=!Quiet
@wait 5=@pemit me=Second part completed.  You may begin the next part. (Only do them in sequence.)