@@
@@ DarrienSpace Installer, Version 1
@@ This is part 8.  There is at least one other section after this one.
@@ Please do the previous sections in order before executing this one.
@@ No editing of this file should be necessary for PennMUSH
@@
@@ I haven't tested this on Tiny, though.
@@
@@ It also shouldn't be necessary to pre-create objects
@@
@@
@@
@set me=Quiet
@@ Okay, now for something that currently, will need to be modified heavily
@@ to work on your MUSH.  It's the 'Ugnaught' of Ship construction, and is
@@ intended to make creating ships easy.  NOTE: The documentation for updating
@@ this code should be done, and notes here somewhere.  I'll remove this NOTE when
@@ I feel happier with this.
@@
@@ NOTE: This object is still being completed on SW1.  I wouldn't even be doing
@@ the decompile if people weren't so damn impatient!!
@@
&DATA_MASTERPARENT Master Ugnaught=#7529
&FUN_ADD-WEAPONSIZES Master Ugnaught=[add(%0,val(extract(get(v(data_weapondb)/type_%1),8,1,|)))]
&FUN_CAN-ADD-WEAPON-MILITARY Master Ugnaught=[setq(6,setdiff(get(v(data_builddb)/[grep(v(data_builddb),*_stat,[before(name(%q1),%b--)])]_weapons),%q3))]
&DATA_SHIPPARENT Master Ugnaught=#7529
&FUN_CAN-ADD-WEAPON Master Ugnaught=[setq(4,squish(iter(lattr(%q1/weapon_*),after(grep(v(data_weapondb),TYPE_*,[extract(get(%q1/##),1,1,|)]|),TYPE_))))][setq(3,fold(fun_add-weaponsizes,%q4,0))][switch(lt(0,extract(get(%q1/stat_stats),11,1,|)),1,[u(fun_can-add-weapon-military)],[u(fun_can-add-weapon-normal)])]
&DATA_ADDITIONS Master Ugnaught=WEAPON
&ADESCRIBE Master Ugnaught=@Pemit %#=START/HELP for help in using him.
&FUN_CAN-ADD Master Ugnaught=[setq(1,switch(isdbref(last(first(%0,=))),1,last(first(%0,=)),get(v(data_shipdb)/trans_[last(first(%0,=))])))][t(member(v(data_additions),setr(0,first(after(%0,=)))))][isdbref(%q1)][or(nearby(me,%q1),u(fun_isdocked))][t(u(fun_can-add-%q0,%q1,last(%0,=)))][hasattr(me,DATA_CANUPGRADE)]
&DO_START_ADD Master Ugnaught=@pemit %1=[switch(u(fun_can-add,%0),0*,<SHIP UPGRADES> Error: '%q0' isn't something that can be added.  Check START/HELP for help.,10*,<SHIP UPGRADES> Error: '[last(first(%0,=))]' doesn't appear to be a valid ship DBREF or Transponder.,110*,<SHIP UPGRADES> Error: The ship is not within range of this facility.,1110*,<SHIP UPGRADES> Error: There is a problem with that particular type of upgrade. The error is:%r%q8%r,11110,<SHIP UPGRADES> Error: This facility is incapable of performing upgrades.,11111,<SHIP UPGRADES> Adding task to queue...[switch(words(lattr(me/task*)),0,%rThe task can be completed immediately.,%rThere are other tasks ahead of this one.  Complete those tasks%, or cancel them.  Check START/HELP for details.)][u(fun_pre-final-%q0)])]
&DO_START_HELP2 Master Ugnaught=@pemit %1=%r[u(help_header,UPGRADE)]%rThe command is:  START/UPGRADE <SHIP>=<UPGRADE>,<OPTION>%r- <SHIP> is either a transponder or a ship's DBREF.  The specified ship needs to either be landed in [name(me)]'s hangar, or docked with [name(me)]'s ship.%r- The Possible Upgrades and their Options:%r[ljust(%b%bHULL,15)]This upgrade makes the ship a little tougher.  Hull is the last%r[space(15)]line of defense in ship combat.  Once the Hull has reached zero,%r[space(15)]the ship is cripple.  Also, the higher the ship hull, the more%r[space(15)]difficult it is for the ship take internal damage.  Hull is%r[space(15)]upgraded in multiples, the Options being 1.1, 1.25, or 1.5.%r[ljust(%b%bSHIELDS,15)]This upgrade makes the ship tougher as well.  The higher%r[space(15)]the shields, the longer it takes to inflict actual damage to the%r[space(15)]ship.  It's increased in multiples, the Options being%r[space(15)]1.1, 1.25, and 1.5.%r[ljust(%b%bENGINES,15)]This upgrade makes the ship faster in real space.  The upgrade is%r[space(15)]specified in multiples.  The Options are 1.1, 1.25, and 1.5.%r[ljust(%b%bHYPERDRIVE,15)]This upgrade makes the ship faster in hyperspace.  The upgrade is%r[space(15)]specified by the actual Hyperdrive multiplier.  The Options are%r[space(15)]3, 2, 1.5, 1, .8, and .6.  .5 can be specified at illegal%r[space(15)]upgrade facilities.%r[ljust(%b%bNAVCOMP,15)]This upgrade makes it possible to store more jump calculations%r[space(15)]at one time.  The upgrade is specified by the number of%r[space(15)]calculations.  The Options are 5, 7, 10, 15, 20, and 30.%r[ljust(%b%bSENSORS,15)]This upgrades the ships sensors.  The upgrade is specified%r[space(15)]by how much you want to multiply all the baseline sensor stats%r[space(15)]by.  The Options are 1.25, 1.5, 1.75, and 2.
&HELP_START_HELP2 Master Ugnaught=
&HELP_START_UPGRADE Master Ugnaught=** For help with Upgrading, check START/HELP2. **
&UPGRADE-FINAL-SHIELDS Master Ugnaught=[set(%q1,stat_stats:[replace(get(%q1/stat_stats),3,setr(8,mul(extract(get(%q1/baseline_stats),3,1,|),extract(v(%0),4,1,|))),|)])][set(%q1,dyn_stats:[replace(get(%q1/dyn_stats),4,%q8,|)])]
&UPGRADE-FINAL-NAVCOMP Master Ugnaught=[set(%q1,stat_stats:[replace(get(%q1/stat_stats),9,extract(v(%0),4,1,|),|)])]
&UPGRADE-FINAL-HYPERDRIVE Master Ugnaught=[set(%q1,stat_stats:[replace(get(%q1/stat_stats),7,extract(v(%0),4,1,|),|)])]
&UPGRADE-FINAL-SENSORS Master Ugnaught=[set(%q1,comm_stats:[replace(get(%q1/comm_stats),2,mul(extract(get(%q1/baseline_comm),2,1,|),extract(v(%0),4,1,|)),|)])][set(%q1,comm_stats:[replace(get(%q1/comm_stats),3,mul(extract(get(%q1/baseline_comm),3,1,|),extract(v(%0),4,1,|)),|)])][set(%q1,comm_stats:[replace(get(%q1/comm_stats),4,mul(extract(get(%q1/baseline_comm),4,1,|),extract(v(%0),4,1,|)),|)])]
&UPGRADE-FINAL-HULL Master Ugnaught=[set(%q1,stat_stats:[replace(get(%q1/stat_stats),2,mul(extract(get(%q1/baseline_stats),2,1,|),extract(v(%0),4,1,|)),|)])]
&FUN_ISDOCKED Master Ugnaught=[t(words(iter(lattr(parent(v(data_home))/d_*),switch(match(get(parent(v(data_home))/##),%q1),2,##))))]
&UPGRADE-FINAL-ENGINES Master Ugnaught=[set(%q1,stat_stats:[replace(get(%q1/stat_stats),1,mul(extract(get(%q1/baseline_stats),1,1,|),extract(v(%0),4,1,|)),|)])]
&FUN_CAN-FINISH-NAVCOMP Master Ugnaught=[lt(extract(get(%q1/stat_stats),9,1,|),extract(v(%0),4,1,|))]
&FUN_CAN-FINISH-HYPERDRIVE Master Ugnaught=[gt(extract(get(%q1/stat_stats),7,1,|),extract(v(%0),4,1,|))]
&FUN_CAN-FINISH-SENSORS Master Ugnaught=[lt(fdiv(extract(get(%q1/comm_stats),3,1,|),extract(get(%q1/baseline_comm),3,1,|)),extract(v(%0),4,1,|))]
&FUN_CAN-FINISH-HULL Master Ugnaught=[lt(fdiv(extract(get(%q1/stat_stats),2,1,|),extract(get(%q1/baseline_stats),2,1,|)),extract(v(%0),4,1,|))]
&FUN_CAN-FINISH-SHIELDS Master Ugnaught=[lt(fdiv(extract(get(%q1/stat_stats),3,1,|),extract(get(%q1/baseline_stats),3,1,|)),extract(v(%0),4,1,|))]
&FUN_CAN-FINISH-ENGINES Master Ugnaught=[lt(fdiv(extract(get(%q1/stat_stats),1,1,|),extract(get(%q1/baseline_stats),1,1,|)),extract(v(%0),4,1,|))]
&FINISH_UPGRADE Master Ugnaught=@swi [gte(%0,last(v(%1),|))][or(nearby(me,setr(1,extract(v(%1),2,1,|))),u(fun_isdocked))][u(fun_can-finish-[extract(v(%1),3,1,|)],%1)]=0*,@pemit %2=You apply %0 credits toward the completion of the task.  [setr(4,sub(extract(v(%1),5,1,|),%0))] more credits are required.[set(me,%1:[replace(v(%1),5,%q4,|)])],10*,{@pemit %2=The ship that is target for that upgrade must be in this location for the upgrade to proceed.;give %2=%0 cred},110,{@pemit %2=That is no longer a valid upgrade.;give %2=%0 #122},111,{@pemit %2=Completing task...[u(upgrade-final-[extract(v(%1),3,1,|)],%1)];give %2=[sub(%0,val(extract(v(%1),5,1,|)))] cred;@wipe me/%1}
&DATA_ENGINES-UPGRADES Master Ugnaught=1.1 1.25 1.5|50 100 300
&FUN_PRE-FINAL-ENGINES Master Ugnaught=%rThe cost for the upgrade will be: [setr(7,mul(extract(get(%q1/baseline_stats),1,1,|),extract(last(v(data_engines-upgrades),|),member(first(v(data_engines-upgrades),|),%q4),1)))].[set(me,task_[secs()]:UPGRADE|%q1|ENGINES|%q4|%q7)]
&FUN_PRE-FINAL-SENSORS Master Ugnaught=%rThe cost for the upgrade will be: [setq(0,0)][iter(get(%q1/baseline_comm),setq(0,add(%q0,##)),|)][setr(7,round(mul(fdiv(%q0,5),%q4),0))].[set(me,task_[secs()]:UPGRADE|%q1|SENSORS|%q4|%q7)]
&DATA_SHIELD-UPGRADES Master Ugnaught=1.1 1.25 1.5|5 10 30
&FUN_PRE-FINAL-SHIELDS Master Ugnaught=%rThe cost for the upgrade will be: [setr(7,mul(extract(get(%q1/baseline_stats),3,1,|),extract(last(v(data_shield-upgrades),|),member(first(v(data_shield-upgrades),|),%q4),1),10))].[set(me,task_[secs()]:UPGRADE|%q1|SHIELDS|%q4|%q7)]
&FUN_PRE-FINAL-NAVCOMP Master Ugnaught=%rThe cost for the upgrade will be: [setr(7,extract(last(v(data_navcomp-upgrades),|),member(first(v(data_navcomp-upgrades),|),%q4),1))].[set(me,task_[secs()]:UPGRADE|%q1|NAVCOMP|%q4|%q7)]
&FUN_PRE-FINAL-HULL Master Ugnaught=%rThe cost for the upgrade will be: [setr(7,mul(extract(get(%q1/baseline_stats),2,1,|),extract(last(v(data_hull-upgrades),|),member(first(v(data_hull-upgrades),|),%q4),1)))].[set(me,task_[secs()]:UPGRADE|%q1|HULL|%q4|%q7)]
&DATA_WEAPONDB Master Ugnaught=#3444
&FUN_DESTINATION Master Ugnaught=[switch(hasattr(me,docked),1,1,switch(loc(v(ship)),v(space),0,v(hyperspace),0,1))]
&FUN_SET-STATS Master Ugnaught=[set(%q1,stat_stats:[extract(v(%0_stat),2,11,|)])][set(%q1,comm_stats:[v(%0_comm)])][set(%q1,dyn_stats:[elements([get(%q1/stat_stats)]|0|1|Normal,12 2 2 3 14 6 13 4 5 12 12,|)])][set(%q1,code:temp)][set(%q1,airlock:%q4)][set(%q1,cockpit:%q2)][switch(extract(get(%q1/dyn_stats),7,1,|),1,set(%q1,d_normal:%q4))][switch(t(words(v(%0_weapons))),1,iter(lnum(1,words(v(%0_weapons))),set(%q1,weapon_##:[get(v(data_weapondb)/type_[extract(v(%0_weapons),##,1)])])))][set(%q1,combat_stats:[switch(t(v(%0_combat)),1,v(%0_combat),0|0|0|0|0|0|0|0|0)])][switch(t(v(%0_cargo)),1,set(%q1,cargo:%q5))][set(%q1,com:5000.00 1312.7  [iter(lnum(3,extract(get(%q1/comm_stats),1,1,|)),0)])][pemit(me,[parent(%q2,%q1)][parent(%q5,%q1)][set(%q2,transparent)][set(%q5,transparent)][set(%q2,floating)][set(%q5,floating)][link(%q4,v(data_home))][set(%q4,destination:[v(fun_destination)])][set(%q4,ship:%q1)][set(%q4,space:[v(space)])][set(%q4,hyperspace:[v(hyperspace)])][link(%q4,destination/1)][set(%q2,describe:A Temporary Description)][set(%q5,describe:A Temporary Description)])]
&FUN_GETTRANS2 Master Ugnaught=[switch(words(lattr(v(data_shipdb)/*[setr(0,rand(10000))])),0,%q0,u(fun_gettrans1))]
&FUN_GETTRANS1 Master Ugnaught=[switch(words(lattr(v(data_shipdb)/*[setr(0,rand(10000))])),0,%q0,u(fun_gettrans2))]
&CMD_BUILD-STOCK Master Ugnaught=$build stock *,*:@pemit %#=[switch([u(fun_can-build?,setr(0,secure(%0)),setr(1,secure(%1)))]1,0*,<SHIP CREATION> '%q0' isn't a valid alias for a ship type.  Check LIST TYPES for a complete list of ships that can be built from here.,10,<SHIP CREATION> There is currently not enough room in this hangar for a ship of that type.,110*,<SHIP CREATION> Minimum deposit of '%q2' required for construction of that ship type.,1110,<SHIP CREATION> You must be a Wizard for this command to work.,1111,<SHIP CREATION> Setting it up![set(me,BUILDING:ON)])];@swi v(building)=ON,@tr me/do_build={%q0,%q1}
&FUN_CAN-BUILD? Master Ugnaught=[or(hasattr(v(data_builddb),%0_stat),hasattr(me,%0_stat))][lte(extract(v(%0_stat),11,1,|),extract(get([setr(8,get(v(data_home)/ship))]/hangar_[setr(9,get(v(data_home)/hangar_name))]),3,1))][not(setr(2,v(%0_cost)))]
&DO_BUILD Master Ugnaught=@remit here=[name(me)] sets about setting up the ship.[u(fun_build-body,%0,%1)][u(fun_create-rooms,%0,%1)][u(fun_set-stats,%0,%1)][u(fun_make-parts,%0,%1)][u(fun_update-db)][tel(me,v(data_home))]%r[name(me)] steps back from the new ship.[wipe(me/building)];+bbpost Building Inspection/SHIP Constr. [after(name(%q1),--%b)]=%q1 has been built by [name(me)].%r%rIt needs to be inspected when a builder has a chance.%r%rCockpit DBREF: [get(%q1/cockpit)];@swi hasattr(me,Data_BC)=1,@dolist [setdiff([lexits(%q2)] [lexits(%q5)] %q2 %q5,%q4)]={@chown ##=[v(data_bc)];@set ##=!halt}
&FUN_BUILD-BODY Master Ugnaught=[setq(1,[create([extract(v(%0_stat),1,1,|)] -- %1)])][set(%q1,trans:[switch(first(name(%q1)),CAPITAL:,CS-,SF-)][set(%q1,safe)][lock(%q1,=*Space_Wizard)][switch(words(lattr(v(data_shipdb)/trans_*[after(%q1,#)])),0,after(%q1,#),u(fun_gettrans1))])][set(%q1,!no_command)][pemit(me,parent(%q1,v(data_masterparent)))]
&DATA_BUILDDB Master Ugnaught=#3868
&DATA_SHIPDB Master Ugnaught=#8297
&FUN_CREATE-ROOMS Master Ugnaught=[tel(me,setr(2,dig(Cockpit - %1)))][switch(extract(v(%0_stat),13,1,|),0,setq(4,open(<OUT>;out,)),[tel(me,setr(5,loc(open(<A>ft;aft;a,dig(Aft - %1)))))][pemit(me,open(<F>ore;fore;f,%q2))][setq(4,open(<OUT>;out;,))])][set(%q4,success:[v(data_exit-success)])][set(%q4,osuccess:[v(data_exit-osuccess)])][set(%q4,odrop:[v(data_exit-odrop)])][set(%q4,describe:[v(data_exit-desc)])][set(%q4,size_lock:3)][set(%q1,otport:[v(data_otport)])][set(%q1,oxtport:[v(data_oxtport)])]
&FUN_UPDATE-DB Master Ugnaught=[set(v(data_shipdb),trans_[get(%q1/trans)]:%q1)][set(%q8,hangar_%q9:[replace(get(%q8/hangar_%q9),3,sub(extract(get(%q8/hangar_%q9),3,1),extract(get(%q1/stat_stats),10,1,|)))])][tel(%q1,v(data_home))]
&FUN_MAKE-PARTS Master Ugnaught=[tel(setr(6,create(Nav-Comp)),%q2)][set(%q6,space:[v(space)])][set(%q6,hyperspace:[v(hyperspace)])][set(%q6,ship:%q1)][switch(t(v(%0_cargo)),1,[tel(setr(7,create(Cargo Computer)),%q5)][set(%q7,data_free_space:[v(%0_cargo)])][set(%q7,data_total_space:[v(%0_cargo)])])][pemit(me,[parent(%q6,v(data_navcomp))][parent(%q7,v(data_cargo))])][set(%q6,!no_command)][set(%q6,wizard)][set(%q7,!no_command)]
&DATA_CARGO Master Ugnaught=#1896
&DATA_NAVCOMP Master Ugnaught=#8880
&DATA_SYSTEMDB Master Ugnaught=#3862
&CMD_LIST-STANDARD Master Ugnaught=$list stock ships:@pemit %#=[ljust(----=< Stock Ships >=,76,-)]%r[ljust(ALIAS,20)]Name[iter(sort(lattr(setr(0,v(data_builddb))/*_stat)),%r[ljust(before(##,_STAT),20,.)][extract(get(%q0/##),1,1,|)])]%r[repeat(-,76)]
@@ End of part 1.
@set me=!Quiet
@wait 5=@pemit me=Eigth part completed.  You may begin the next part. (Only do them in sequence.)